def localProperties = new Properties()
def localPropertiesFile = rootProject.file('local.properties')
if (localPropertiesFile.exists()) {
    localPropertiesFile.withInputStream { stream ->
        localProperties.load(stream)
    }
}

def flutterRoot = localProperties.getProperty('flutter.sdk')
if (flutterRoot == null) {
    throw new GradleException("Flutter SDK not found. Define location with flutter.sdk in the local.properties file.")
}

apply plugin: 'com.android.application'
apply from: "$flutterRoot/packages/flutter_tools/gradle/flutter.gradle"

android {
    compileSdkVersion 25
    buildToolsVersion '25.0.0'

    lintOptions {
        disable 'InvalidPackage'
    }

    defaultConfig {
        targetSdkVersion 21
        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
        applicationId "com.dinect.checker"
    }

    buildTypes {
        debug {
            debuggable true
            signingConfig signingConfigs.debug
        }
        release {
            signingConfig signingConfigs.debug
        }
    }

    // Не смог разобраться, как коомбинировать flavors в flutter при запуске

    productFlavors {

        autobonus {
            applicationId 'com.dinect.autobonus'
            buildConfigField "String", "locale", "\"ru\""
            buildConfigField "String", "flavor", "\"autobonus\""
            buildConfigField "int", "currency", "643"
            buildConfigField "String", "support", "\"8-800-234-6064\""
        }

        pip {
            applicationId 'com.dinect.pip'
            buildConfigField "String", "locale", "\"ua\""
            buildConfigField "String", "flavor", "\"pip\""
            buildConfigField "int", "currency", "980"
            buildConfigField "String", "support", "\"+38 080 030 9997\\n+38 044 390 1697\""
        }

    }

    sourceSets {

        main.jniLibs.srcDir 'jniLibs'

        pip {
            res.srcDirs = ['src/pip/res']
            manifest.srcFile 'src/pip/AndroidManifest.xml'
        }

    }
}

flutter {
    source '../..'
}

dependencies {
    compile fileTree(dir: 'libs', include: ['*.jar'])
    compile 'com.android.support:appcompat-v7:25.3.1'
    compile 'com.squareup.okhttp3:okhttp:3.8.1'
    compile 'com.squareup.okio:okio:1.13.0'
    compile 'me.dm7.barcodescanner:zxing:1.9.8'
}